通达信公式副图 多维动态趋势预警

公式代码：

{AIGUQI.COM}

N1:=3;N2:=10;M1:=5;M2:=20;

LC:= REF(CLOSE,1);

RSI1:=SMA(MAX(CLOSE - LC,0),N1,1)/SMA(ABS(CLOSE - LC),N1,1)*100;

RSI2:=SMA(MAX(CLOSE - LC,0),N2,1)/SMA(ABS(CLOSE - LC),N2,1)*100;

买:EMA(RSI1,M1),COLORRED,LINETHICK2;

卖:EMA(RSI2,M2),LINETHICK2,COLORFFFF00;

VAR1:=REF(CLOSE,1);

VAR2:SMA(MAX(CLOSE - VAR1,0),6,1)/SMA(ABS(CLOSE - VAR1),6,1)*100;

VAR3:=(CLOSE - LLV(LOW,20))/(HHV(HIGH,20) - LLV(LOW,20))*100;

VAR4:SMA(SMA(VAR3,3,1),3,1),COLOR00FF00;

VAR5:=EMA(VAR4,5);

VAR7:=3*VAR4 - 2*VAR5,COLORGREEN;

UPTJ1:=CLOSE>REF(CLOSE,1);

UPTJ2:=(CLOSE==REF(CLOSE,1) && REF(CLOSE,1)>REF(CLOSE,2));

UPTJ3:=MAX(OPEN,CLOSE)<REF(C,BARSLAST(CLOSE>REF(CLOSE,1))) AND MIN(OPEN,CLOSE)>REF(O,BARSLAST(CLOSE>REF(CLOSE,1)));

UPTJ4:=NOT (H<REF(H,1) AND L<REF(L,1));

UP:=(UPTJ1 || UPTJ2 || UPTJ3) AND UPTJ4;

DOWN:=NOT(UP);

M1_WSB:=BARSLASTCOUNT(UP);

N1_WSB:=BARSLASTCOUNT(DOWN);

CZB:=IF(M1_WSB=1 OR N1_WSB=1,2*INTPART(VOL*100/10000),INTPART(VOL*100/10000));

SZ:=IF(M1_WSB>0,SUM(CZB,M1_WSB),-1*SUM(CZB,N1_WSB));

GY:=IF(N1_WSB>0,SUM(CZB,N1_WSB),0);

XQ:=IF(M1_WSB>0,SUM(CZB,M1_WSB),0);

跌预警:CROSS(70,VAR2) AND CLOSE<MA(CLOSE,2),COLOR00FF00,LINETHICK2;

DRAWICON(CROSS(VAR2,买) AND VAR4>70,买*1.15,2);

DRAWTEXT(CROSS(VAR2,买) AND VAR4>70,买,'出'),COLOR00FF00;

涨预警:CROSS(VAR2,30) AND VOL > REF(VOL,3) * 1.10,COLORYELLOW,STICK;

DRAWTEXT(CROSS(买,卖) AND 买<45,VAR4,'进');

DRAWICON(CROSS(买,卖)>0 AND 买<45,VAR4,1);

{超买且上涨成交量萎缩}

强卖信号:=(跌预警 AND XQ < REF(XQ,2));

DRAWICON(强卖信号,卖*1.05,43);

DRAWTEXT(强卖信号,卖*0.88,'袭'),COLORGREEN;

{超卖且下跌成交量萎缩}

强买信号:=(涨预警 AND GY < REF(GY,2));

DRAWICON(强买信号,买*0.95,42);

DRAWTEXT(强买信号,买,'拉'),COLORRED;

NOTEXT1:STICKLINE(M1_WSB>0,0,XQ,1,0),COLORRED,NODRAW;

NOTEXT2:STICKLINE(N1_WSB>0,0,GY,1,0),COLORGREEN,NODRAW;

WSB:SZ,NODRAW;

分界:45,COLORFF0000;

顶:90,COLORYELLOW,LINETHICK2;

@

承蒙您喜欢

非常希望得到您的  “分享"  和  “在看” 。

通达信多维动态趋势预警公式指南

跌预警信号

信号触发条件：当 VAR2 向上穿过 70（超买区）且收盘价小于 2 日移动平均线时触发，即 CROSS(70,VAR2) AND CLOSE<MA(CLOSE,2)。 

含义与逻辑：VAR2 进入超买区表明市场短期内可能过热，股价有回调需求。同时收盘价小于 2 日移动平均线，进一步确认股价短期走弱趋势，综合提示股价可能下跌。 

涨预警信号

信号触发条件：当 VAR2 向上穿过 30（超卖区）且成交量大于前 3 日成交量的 1.1 倍时触发，即 CROSS(VAR2,30) AND VOL > REF(VOL,3) * 1.10。 

含义与逻辑：VAR2 从超卖区回升，显示市场短期内可能超跌反弹。成交量大幅放大，意味着市场活跃度增加且有资金流入推动股价上涨，两者结合提示股价可能上涨。 

卖出信号

信号触发条件：当 VAR2 向上穿过 买 线且 VAR4 大于 70 时触发，即 CROSS(VAR2,买) AND VAR4>70。 

含义与逻辑：VAR2 向上穿过 买 线，表明短期波动指标超越短期趋势指标，可能趋势反转。VAR4 大于 70 也显示市场处于较强状态，此时卖出可锁定利润或避免潜在下跌风险。 

买入信号

信号触发条件：当 买 线向上穿过 卖 线且 买 线小于 45 时触发，即 CROSS(买,卖) AND 买<45。 

含义与逻辑：买 线向上穿过 卖 线，意味着短期趋势向上突破长期趋势，可能开启上涨行情。买 线小于 45 表明市场处于相对低位，此时买入可能获取后续上涨收益。 

强卖信号

信号触发条件：当出现跌预警且上涨成交量 XQ 小于前 2 日上涨成交量时触发，即 (跌预警 AND XQ < REF(XQ,2))。 

含义与逻辑：在股价有下跌预警基础上，上涨成交量萎缩，说明上涨动力不足，市场资金追涨意愿降低，进一步强化了股价下跌趋势，应及时卖出。 

强买信号

信号触发条件：当出现涨预警且下跌成交量 GY 小于前 2 日下跌成交量时触发，即 (涨预警 AND GY < REF(GY,2))。 

含义与逻辑：在股价有上涨预警时，下跌成交量萎缩，意味着市场抛压减轻，多方力量相对增强，进一步确认股价上涨趋势，可考虑买入。 

使用方法