股票期货投资利器-通达信MACD指标增强版交易决策指标公式

不迷信指标 但为我所用

MACD指标

增强版

交易决策

Index Formulas

通达信副图

通达信指标安装技巧：

1、电脑端 打开通达信软件；点击“功能”-“公式系统”-“公式管理器”；选择“技术指标公式”-“新建”；填写名称并复制粘贴公式，填写必需的参数；

2、点击右上角的”测试公式“对你的新增指标进行测试，测试结果会在最下方显示。通过的话，一定要记得去点击右上角的”确定“按钮，这样你的新增指标就完成了。

3、手机版 找到“我的指标”→自编在云（选本地也行）→创建云指标 →填写指标信息→填写源码编译→右上角最右边点选  保存→回股票界面选择 技术指标→“我的指标”里 对应找到

前 言

通达信MACD指标增强版交易决策指标公式是通达信副图指标，主要基于MACD指标（移动平均收敛/发散指标）进行设计。该公式通过计算不同时间段的指数移动平均线（EMA）的差异（DIF和DEA），以及MACD值，来识别股票的买入和卖出信号。公式中包含了多种条件判断，如低位金叉、高位死叉、二次金叉、二次死叉、底背离和顶背离等，其主要的设计思路和逻辑如下：

技术指标计算

MACD 指标：通过计算短期指数移动平均线（EMA）和长期 EMA 的差值（DIF），以及 DIF 的指数移动平均线（DEA），得到 MACD 指标。MACD 指标的柱状图表示 DIF 与 DEA 的差值。 

其他指标：还计算了一些其他的指标，如阻力价（阻价）、支撑价（支价）等，用于辅助分析价格走势。 

买卖信号判断

多空判断：根据价格的走势、均线的排列、MACD 指标的变化等条件，判断市场的多空情况，并给出多空信号。 

买卖点判断：通过金叉、死叉等信号判断买卖点。低位金叉表示买入信号，高位死叉表示卖出信号。二次金叉和二次死叉则是对金叉和死叉的进一步确认。 

背离判断：通过比较价格和指标的走势，判断是否出现背离。底背离表示价格可能见底，顶背离表示价格可能见顶。 

信号显示和提示

图标显示：使用图标（如箭头、圆点等）在图表上显示买卖信号。 

文字提示：使用文字说明买卖信号的名称和含义。 

综合判断

三振多和三振空：结合低位金叉、二次金叉和底背离等多个信号，判断是否出现三振多的情况；结合高位死叉、二次死叉和顶背离等多个信号，判断是否出现三振空的情况。 

入 1 和入 2：根据 DIF 的变化，显示红色或绿色的线条，表示当前价格相对于前一周期的变化趋势。 

根据上述设计逻辑和思路，通达信MACD指标增强版交易决策指标公式适合在以下环境中使用：

震荡行情: 指标中包含均线系统、金叉和死叉信号、支撑阻力位判断等，适合在震荡行情中寻找买卖时机。

趋势行情: 指标中包含 MACD指标、DIF-DEA 等趋势指标，适合在趋势行情中判断趋势方向和买卖时机。

活跃市场: 指标中包含成交量指标，适合在成交量活跃的市场中交易。

短线交易：包含了多个用于生成买入和卖出信号的条件，如VV1、VV2、二次翻红、低买、加仓等，这些信号通常用于捕捉短期内的价格波动。

中长线交易：定义了多个不同周期的EMA值（如E3到E1920），这些可以用于分析中期至长期的价格趋势。

长线交易：长线交易者更关注长期趋势和市场的整体状况。虽然该公式也提供了一些长期指标，但长线交易通常需要更多的基本面分析和宏观经济因素的考量，而不仅仅是技术指标。

多周期分析：通过结合不同周期的EMA和MACD指标，交易者可以进行多周期分析，这有助于识别不同时间尺度上的趋势和潜在的交易机会。

通达信MACD指标增强版交易决策指标公式，不仅包括了传统的MACD指标，还扩展了信号的识别和显示，以及价格支撑和阻力的计算，旨在帮助交易者更好地理解市场动态并做出交易决策。适用于趋势明显或有一定波动性的市场环境，既可以用于短线操作，也可以用于中长线操作。期货交易同样适用，但需注意风险管理。

 ○ 公式代码 ○

Formula Code

指标代码：

DIFF:= EMA(CLOSE,12) - EMA(CLOSE,26);

DIF:EMA(CLOSE,12)-EMA(CLOSE,26),LINETHICK2;

DEA:EMA(DIF,9),COLORWHITE;

MACD:(DIF-DEA)*2,NODRAW;

DRAWBAND(DIF,RGB(150,20,20),DEA,RGB(10,150,20));

DRAWBAND(IF(DIF,DIF,DRAWNULL),RGB(250,250,250),DIF,RGB(0,0,0));

DRAWBAND(IF(DEA,DEA,DRAWNULL),RGB(250,250,10),DEA,RGB(0,0,0));

STICKLINE(MACD>0,0,MACD,1,0),COLORRED;

STICKLINE(MACD<0,0,MACD,1,0),COLORGREEN;

STICKLINE(MACD>0 AND MACD<=REF(MACD,1),0,MACD,1,0),COLORYELLOW;

STICKLINE(MACD<0 AND MACD>=REF(MACD,1),0,MACD,1,0),COLORWHITE;

FH1:=REF(MACD,1)<REF(MACD,2) AND REF(MACD,2)<REF(MACD,3) AND REF(MACD,3)<REF(MACD,4);

FH2:=MACD>=0 AND COUNT(MACD>REF(MACD,1),1)=1;

FH3:=FH1 AND FH2 AND EMA(C,13)>REF(EMA(C,13),1);

FH4:=FH1 AND FH2 AND ABS((DIF-DEA)/C)<0.018;

FH5:=FH1 AND FH2 AND MACD<0.10;

VV1:=CLOSE>OPEN AND MA(CLOSE,5)>MA(CLOSE,10) AND MA(CLOSE,10)>MA(CLOSE,30)

AND DIFF>DEA AND MACD>REF(MACD,1) AND DIFF>0 AND DEA>0 AND

MA(VOL,5)>MA(VOL,34) AND MA(CLOSE,30)>=REF(MA(CLOSE,30),1);

多:IF(VV1,1,0),NODRAW;

DRAWICON(多,0.06,42);

VV2:=CLOSE<OPEN AND MA(CLOSE,5)<MA(CLOSE,10) AND MA(CLOSE,10)<MA(CLOSE,30)

AND DIFF<DEA AND MACD<REF(MACD,1) AND DIFF<0 AND DEA<0 AND

MA(VOL,5)<MA(VOL,34) AND MA(CLOSE,30)<=REF(MA(CLOSE,30),1);

空:IF(VV2,1,0),NODRAW;

DRAWICON(空,0.06,43);

二次翻红:(FH3 OR FH4 OR FH5),COLORRED,NODRAW;

低买:CROSS(DIF,DEA) AND DIF<0,COLORBLUE,NODRAW;

加仓:CROSS(DIF,DEA) AND DIF>0,COLORYELLOW,NODRAW;

DRAWICON(二次翻红,-0.05,1);

DRAWTEXT(二次翻红,-0.15,'翻红'),COLORRED;

DRAWTEXT(CROSS(DIF,DEA) AND DIF<0,DEA-0.02,'低买'),COLORBLUE;

DRAWTEXT(CROSS(DIF,DEA) AND DIF>0,DEA-0.05,'加仓'),COLORYELLOW;

XG:二次翻红 OR 低买 OR 加仓,NODRAW;

YLZC:=IF(CLOSE=INDEXC,(INDEXC+INDEXH+INDEXL+INDEXO)/4,AMOUNT/(VOL+0.01)/100);

阻价:=IF(CLOSE=INDEXC,YLZC+INDEXC-INDEXL,YLZC+(CLOSE-LOW));

支价:=IF(CLOSE=INDEXC,INDEXL+INDEXC-YLZC,LOW+(CLOSE-YLZC));

今压:REF(阻价,1),LINETHICK0,COLORAA11BB,NODRAW;

今撑:REF(支价,1),LINETHICK0,COLOR009900,NODRAW;

明压:阻价,LINETHICK0,NODRAW;

明撑:支价,LINETHICK0,NODRAW;

低位金叉:=CROSS(DIFF,DEA) AND DIFF<-0.1;

STICKLINE(低位金叉,0,0.08,6,0),COLOR4080FF;

DRAWTEXT(低位金叉,0.16,' 低位金叉'),COLOR4080FF;

高位死叉:=CROSS(DEA,DIFF) AND DEA>0.1;

STICKLINE(高位死叉,0,0.08,6,0),COLORFF8000;

DRAWTEXT(高位死叉,0.16,' 高位死叉'),COLORFF8000;

JCCOUNT:=COUNT(CROSS(DIFF,DEA),BARSLAST(DEA>=0));

二次金叉:=CROSS(DIFF,DEA) AND DEA<0 AND COUNT(JCCOUNT=2,21)=1;

STICKLINE(二次金叉,0,0.06,6,0),COLORBLUE;

DRAWICON(二次金叉,DEA*0.9,1) ;

DRAWTEXT(二次金叉,0.2,' 二次金叉'),COLORYELLOW;

JCCOUNT1:=COUNT(CROSS(DEA,DIFF),BARSLAST(DEA<=0));

二次死叉:=CROSS(DEA,DIFF) AND DEA>0 AND COUNT(JCCOUNT1=2,21)=1;

STICKLINE(二次死叉,0,0.06,6,0),COLORGREEN;

DRAWICON(二次死叉,DEA*0.9,1);

DRAWTEXT(二次死叉,0.2,' 二次死叉'),COLORWHITE;

B1:=BARSLAST(REF(CROSS(DIFF,DEA),1));

底背离:=REF(CLOSE,B1+1)>CLOSE AND DIFF>REF(DIFF,B1+1) AND CROSS(DIFF,DEA);

STICKLINE(底背离,0,0.03,6,0),COLORFF0080;

DRAWTEXT(底背离,0.12,' 底背离'),COLORFF0080;

B2:=BARSLAST(REF(CROSS(DEA,DIFF),1));

顶背离:=REF(CLOSE,B2+1)<CLOSE AND REF(DIFF,B2+1)>DIFF AND CROSS(DEA,DIFF);

STICKLINE(顶背离,0,0.03,6,0),COLORFFFF00;

DRAWTEXT(顶背离,0.12,' 顶背离'),COLORFFFF00;

DRAWTEXT(低位金叉 AND 二次金叉 AND 底背离,0.25,'三振多'),COLOR0000FF,LINETHICK2;

DRAWTEXT(高位死叉 AND 二次死叉 AND 顶背离,0.25,'三振空'),COLORFF00FF,LINETHICK2;

入1:IF(DIF>REF(DIF,1),DIF,DRAWNULL),COLORRED,LINETHICK2;

入2:IF(DIF<REF(DIF,1),DIF,DRAWNULL),COLOR00FF00,LINETHICK2;

E3:=EMA(DIF,3);

E5:=EMA(DIF,5);

E10:=EMA(DIF,10);

E20:=EMA(DIF,20);

E60:=EMA(DIF,60);

E120:=EMA(DIF,120);

E240:=EMA(DIF,240);

E480:=EMA(DIF,480);

E960:=EMA(DIF,960);

E1920:=EMA(DIF,1920);

EE:=(E3*3+E5*5+E10*10+E20*20+E60*60+E120*120+E240*240+E480*480+E960*960+E1920*1920)/3818;

EE1:=(E3*3+E5*5)/8;

EE2:=(E20*20+E60*60+E120*120+E240*240+E480*480)/920;

EE3:=(E3*3+E5*5+E10*10)/18;

CE1:=((((EE2+EE3)/2+DIF)/2+DIF)/2+DIF)/2;

TT:EE2*(1+0.01*344),CIRCLEDOT,COLOR0000FF;

效果图示

图片请点击放大查看

---

@

承蒙您喜欢

非常希望得到您的“分享"和“在看”

提示

通达信MACD指标增强版交易决策指标公式主要信号及用法详解：

【买卖信号】

多单信号

MACD 翻红: MACD 由负转正，表明趋势由跌转涨。

低位金叉: DIF 和 DEA 在低位金叉，表明短期趋势转强。

二次翻红: MACD 在低位连续两次翻红，表明上涨动力强劲。

低买: DIF 和 DEA 在低位金叉，DIF < 0，表明低位买入时机。

二次金叉：DIF 上穿 DEA 且 DEA 小于 0，且在过去 21 天内有两次 DIF 上穿 DEA。

底背离：当价格创出新低，但MACD指标没有创出新低时，形成底背离。这可能表明虽然价格仍在下跌，但下跌动能在减弱，可能预示着市场即将反转向上。 

加仓: DIF 和 DEA 在高位金叉，DIF > 0，表明上涨趋势延续。

三振多: 低位金叉、二次金叉、底背离同时出现，表明强烈做多信号。（三项共振）

空单信号

MACD 翻绿: MACD 由正转负，表明趋势由涨转跌。

高位死叉: DIF 和 DEA 在高位死叉，表明短期趋势转弱。

高卖: DIF 和 DEA 在高位死叉，DIF < 0，表明高位卖出时机。

二次死叉：DEA 上穿 DIF 且 DEA 大于 0，且在过去 21 天内有两次 DEA 上穿 DIF。

顶背离：与底背离相反，当价格创出新高，但MACD指标没有创出新高时，形成顶背离。这可能表明虽然价格仍在上涨，但上涨动能在减弱，可能预示着市场即将反转向下。

三振空: 高位死叉、二次死叉、顶背离同时出现，表明强烈做空信号。（三项共振）

【其他指标】

今压/今撑/明压/明撑: 判断短期支撑和阻力位。

阻价/支价: 判断长期支撑和阻力位。

E3, E5, …, EE1920: 使用多个周期的 DIF EMA，计算综合指标 EE，用于判断趋势的强弱。

TT: 使用 EE2 和 EE3 计算 TT 指标，用于判断买卖时机。

【弊端】

滞后性：技术指标通常基于历史数据计算，可能在市场趋势已经形成后才能识别出来，这可能导致交易信号的滞后。

假信号：由于市场的随机波动，指标可能会产生误导性的信号，特别是在震荡市场中。

依赖单一指标：过分依赖单一指标可能导致忽视其他重要的市场信息和基本面分析。

心理偏差：交易者可能会因为确认偏误等心理因素，只关注支持自己观点的信号，而忽视相反的信号。

使用建议

结合多种指标：不要单独依赖一个指标，应该结合多个技术指标和基本面分析来做出交易决策。

技术和基本面结合：将技术分析与基本面分析相结合，以获得更全面的市场视角。

风险管理：无论指标如何显示，始终要有明确的入场和退出策略，以及风险控制措施。

翻译参考

DIFF赋值: 收盘价的12日指数移动平均 - 收盘价的26日指数移动平均

输出DIF:收盘价的12日指数移动平均-收盘价的26日指数移动平均,线宽为2

输出DEA:DIF的9日指数移动平均,画白色

输出平滑异同平均线:(DIF-DEA)*2,NODRAW

画带状线

画带状线

画带状线

当满足条件MACD>0时,在0和MACD位置之间画柱状线,宽度为1,0不为0则画空心柱.,画红色

当满足条件MACD<0时,在0和MACD位置之间画柱状线,宽度为1,0不为0则画空心柱.,画绿色

当满足条件MACD>0ANDMACD<=1日前的MACD时,在0和MACD位置之间画柱状线,宽度为1,0不为0则画空心柱.,画黄色

当满足条件MACD<0ANDMACD>=1日前的MACD时,在0和MACD位置之间画柱状线,宽度为1,0不为0则画空心柱.,画白色

FH1赋值:1日前的MACD<2日前的MACD AND 2日前的MACD<3日前的MACD AND 3日前的MACD<4日前的MACD

FH2赋值:MACD>=0 AND 统计1日中满足MACD>1日前的MACD的天数=1

FH3赋值:FH1 AND FH2 AND 收盘价的13日指数移动平均>1日前的收盘价的13日指数移动平均

FH4赋值:FH1 AND FH2 AND (DIF-DEA)/收盘价的绝对值<0.018

FH5赋值:FH1 AND FH2 AND MACD<0.10

VV1赋值:收阳线ANDSE 收盘价的5日简单移动平均>收盘价的10日简单移动平均 AND 收盘价的10日简单移动平均>收盘价的30日简单移动平均AND DIFF>DEA AND MACD>1日前的MACD AND DIFF>0 AND DEA>0 ANDMA(成交量(手),5)>成交量(手)的34日简单移动平均 AND 收盘价的30日简单移动平均>=1日前的收盘价的30日简单移动平均

输出多:如果VV1,返回1,否则返回0,NODRAW

当满足条件多时,在0.06位置画42号图标

VV2赋值:收阴线ANDSE 收盘价的5日简单移动平均<收盘价的10日简单移动平均 AND 收盘价的10日简单移动平均<收盘价的30日简单移动平均AND DIFF<DEA AND MACD<1日前的MACD AND DIFF<0 AND DEA<0 ANDMA(成交量(手),5)<成交量(手)的34日简单移动平均 AND 收盘价的30日简单移动平均<=1日前的收盘价的30日简单移动平均

输出空:如果VV2,返回1,否则返回0,NODRAW

当满足条件空时,在0.06位置画43号图标

输出二次翻红:(FH3 OR FH4 OR FH5),画红色,NODRAW

输出低买:DIF上穿DEA AND DIF<0,画蓝色,NODRAW

输出加仓:DIF上穿DEA AND DIF>0,画黄色,NODRAW

当满足条件二次翻红时,在-0.05位置画1号图标

当满足条件二次翻红时,在-0.15位置书写文字,画红色

当满足条件DIF上穿DEAANDDIF<0时,在DEA-0.02位置书写文字,画蓝色

当满足条件DIF上穿DEAANDDIF>0时,在DEA-0.05位置书写文字,画黄色

输出XG:二次翻红 OR 低买 OR 加仓,NODRAW

YLZC赋值:如果收盘价=大盘的收盘价,返回(大盘的收盘价+大盘的最高价+大盘的最低价+大盘的开盘价)/4,否则返回成交额(元)/(成交量(手)+0.01)/100

阻价赋值:如果收盘价=大盘的收盘价,返回YLZC+大盘的收盘价-大盘的最低价,否则返回YLZC+(收盘价-最低价)

支价赋值:如果收盘价=大盘的收盘价,返回大盘的最低价+大盘的收盘价-YLZC,否则返回最低价+(收盘价-YLZC)

输出今压:1日前的阻价,线宽为0,COLORAA11BB,NODRAW

输出今撑:1日前的支价,线宽为0,COLOR009900,NODRAW

输出明压:阻价,线宽为0,NODRAW

输出明撑:支价,线宽为0,NODRAW

低位金叉赋值:DIFF上穿DEA AND DIFF<-0.1

当满足条件低位金叉时,在0和0.08位置之间画柱状线,宽度为6,0不为0则画空心柱.,COLOR4080FF

当满足条件低位金叉时,在0.16位置书写文字,COLOR4080FF

高位死叉赋值:DEA上穿DIFF AND DEA>0.1

当满足条件高位死叉时,在0和0.08位置之间画柱状线,宽度为6,0不为0则画空心柱.,COLORFF8000

当满足条件高位死叉时,在0.16位置书写文字,COLORFF8000

JCCOUNT赋值:统计上次DEA>=0距今天数日中满足DIFF上穿DEA的天数

二次金叉赋值:DIFF上穿DEA AND DEA<0 AND 统计21日中满足JCCOUNT=2的天数=1

当满足条件二次金叉时,在0和0.06位置之间画柱状线,宽度为6,0不为0则画空心柱.,画蓝色

当满足条件二次金叉时,在DEA*0.9位置画1号图标 

当满足条件二次金叉时,在0.2位置书写文字,画黄色

JCCOUNT1赋值:统计上次DEA<=0距今天数日中满足DEA上穿DIFF的天数

二次死叉赋值:DEA上穿DIFF AND DEA>0 AND 统计21日中满足JCCOUNT1=2的天数=1

当满足条件二次死叉时,在0和0.06位置之间画柱状线,宽度为6,0不为0则画空心柱.,画绿色

当满足条件二次死叉时,在DEA*0.9位置画1号图标

当满足条件二次死叉时,在0.2位置书写文字,画白色

B1赋值:上次1日前的DIFF上穿DEA距今天数

底背离赋值:B1+1日前的收盘价>收盘价 AND DIFF>B1+1日前的DIFF AND DIFF上穿DEA

当满足条件底背离时,在0和0.03位置之间画柱状线,宽度为6,0不为0则画空心柱.,COLORFF0080

当满足条件底背离时,在0.12位置书写文字,COLORFF0080

B2赋值:上次1日前的DEA上穿DIFF距今天数

顶背离赋值:B2+1日前的收盘价<收盘价 AND B2+1日前的DIFF>DIFF AND DEA上穿DIFF

当满足条件顶背离时,在0和0.03位置之间画柱状线,宽度为6,0不为0则画空心柱.,COLORFFFF00

当满足条件顶背离时,在0.12位置书写文字,COLORFFFF00

当满足条件低位金叉AND二次金叉AND底背离时,在0.25位置书写文字,COLOR0000FF,线宽为2

当满足条件高位死叉AND二次死叉AND顶背离时,在0.25位置书写文字,COLORFF00FF,线宽为2

输出入1:如果DIF>1日前的DIF,返回DIF,否则返回无效数,画红色,线宽为2

输出入2:如果DIF<1日前的DIF,返回DIF,否则返回无效数,COLOR00FF00,线宽为2

E3赋值:DIF的3日指数移动平均

E5赋值:DIF的5日指数移动平均

E10赋值:DIF的10日指数移动平均

E20赋值:DIF的20日指数移动平均

E60赋值:DIF的60日指数移动平均

E120赋值:DIF的120日指数移动平均

E240赋值:DIF的240日指数移动平均

E480赋值:DIF的480日指数移动平均

E960赋值:DIF的960日指数移动平均

E1920赋值:DIF的1920日指数移动平均

EE赋值:(E3*3+E5*5+E10*10+E20*20+E60*60+E120*120+E240*240+E480*480+E960*960+E1920*1920)/3818

EE1赋值:(E3*3+E5*5)/8

EE2赋值:(E20*20+E60*60+E120*120+E240*240+E480*480)/920

EE3赋值:(E3*3+E5*5+E10*10)/18

CE1赋值:((((EE2+EE3)/2+DIF)/2+DIF)/2+DIF)/2

输出TT:EE2*(1+0.01*344),CIRCLEDOT,COLOR0000FF

开户咨询•程序化定制编写 •请联系我 

本报告仅供参考，不构成投资建议，不属于交易咨询类报告。投资者据此进行投资，与作者和公众号无关。本报告数据与信息均来自于公开信息和作者授权，但对这些信息的准确性与完整性均不作任何保证。本报告版权为“量化投资交易”公众号所有，未经许可，不得转载。

  END  

 长按二维码 关注

视频号 搜索关注

“量化投资交易”

期货程序化交易免费编写

咨询：17896090076

（同微信号）