技术指标
通达信天龙八步选股指标公式
本选股公式主要用以下逻辑和依据进行选股：
1. MACD指标：通过计算DIFF和DEA指标，判断股票的短期和长期趋势。当DIFF大于DEA时，GPZBGS1为真，表示MACD金叉，是买入信号。
2. 随机指标（KDJ）：通过计算K和D指标，判断股票的动量情况。当K大于D时，GPZBGS2为真，表示KDJ金叉，也是买入信号。
3. 相对强弱指标（RSI）：通过计算RSI1和RSI2指标，判断股票的相对强弱。当RSI1大于RSI2时，GPZBGS3为真，表示RSI金叉，也是买入信号。
4. 威廉指标（WMS）：通过计算LWR1和LWR2指标，判断股票的超买超卖情况。当LWR1大于LWR2时，GPZBGS4为真，表示威廉指标金叉，也是买入信号。
5. 多空指标（BBI）：通过计算BBI指标，判断股票的价格位置。当收盘价大于BBI时，GPZBGS5为真，表示价格处于BBI之上，是买入信号。
6. 能量潮指标（MMS）：通过计算MMS和MMM指标，判断股票的能量情况。当MMS大于MMM时，GPZBGS6为真，表示能量潮金叉，也是买入信号。
7. 资金流向指标（DDX）：通过计算DDX1和DDX2指标，判断资金的流入情况。当DDX1大于DDX2时，GPZBGS7为真，表示资金流向金叉，也是买入信号。
8. 成交量指标：通过计算GSKZ11和GSKZ12指标，判断成交量的变化情况。当GSKZ11大于GSKZ12时，GPZBGS8为真，表示成交量增加，也是买入信号。
9. 换手率：当换手率大于3%时，也是买入信号。
综合上述指标，只有当所有买入条件都满足时，才发出买入信号，表示该股票具备较好的买入机会。本指标公式分八步综合考虑了股票的趋势、动量、相对强弱、超买超卖、价格位置、能量、资金流向和成交量等多方面因素，以判断股票的买入时机，故此选股指标公式称为“天龙八步”。
Formula Code
N1:=3;
N2:=5;
N3:=8;
N4:=13;
DIFF:=EMA(CLOSE,N3)-EMA(CLOSE,N4);
DEA:=EMA(DIFF,N2);
GPZBGS1:=DIFF>DEA;
RSGPZB21:=(CLOSE-LLV(LOW,N3))/(HHV(HIGH,N3)-LLV(LOW,N3))*100;
K:=SMA(RSGPZB21,N1,1);
D:=SMA(K,N1,1);
GPZBGS2:=K>D;
LC:=REF(CLOSE,1);
RSI1:=(SMA(MAX(CLOSE-LC,0),N2,1))/(SMA(ABS(CLOSE-LC),N2,1))*100;
RSI2:=(SMA(MAX(CLOSE-LC,0),N4,1))/(SMA(ABS(CLOSE-LC),N4,1))*100;
GPZBGS3:=RSI1>RSI2;
RSV:=-(HHV(HIGH,N4)-CLOSE)/(HHV(HIGH,N4)-LLV(LOW,N4))*100;
LWR1:=SMA(RSV,N1,1);
LWR2:=SMA(LWR1,N1,1);
GPZBGS4:=LWR1>LWR2;
BBI:=(MA(CLOSE,N1)+MA(CLOSE,N2)+MA(CLOSE,N3)+MA(CLOSE,N4))/4;
GPZBGS5:=CLOSE>BBI;
GPZB:=CLOSE-REF(CLOSE,1);
MMS:=100*EMA(EMA(GPZB,N2),N1)/EMA(EMA(ABS(GPZB),N2),N1);
MMM:=100*EMA(EMA(GPZB,N4),N3)/EMA(EMA(ABS(GPZB),N4),N3);
GPZBGS6:=MMS>MMM;
WJ:=(H+L+C)/3;
GPZB21:=IF(H=L,1,H-MAX(O,C));
GPZB22:=IF(H=L,1,MAX(C,O)-WJ);
GPZB23:=IF(H=L,1,MIN(O,C)-L);
GPZB24:=IF(H=L,1,WJ-MIN(C,O));
GPZB25:=VOL/IF(H=L,4,H-L);
GPZB26:=(GPZB21*GPZB25);
GPZB27:=(GPZB22*GPZB25);
GPZB28:=(GPZB23*GPZB25);
GPZB29:=(GPZB24*GPZB25);
BUYpan:=(GPZB29+GPZB28);
SELLpan:=(GPZB26+GPZB27);
BUYSELLDIFF:=BUYpan-SELLpan;
DDX:=BUYSELLDIFF;
DX:=MA(BUYSELLDIFF,5)*20;
DDX1:=SMA(DX,3,1);
DDX2:=SMA(DDX1,3,1);
DDX3:=(5*DDX2+4*REF(DDX2,1)+3*REF(DDX2,2)+2*REF(DDX2,3)+REF(DDX2,4))/15;
GPZBGS7:=DDX1>DDX2;
LIANG:=V;
换手:=V/CAPITAL*100;
VAR1:=VOL/((HIGH-LOW)*2-ABS(CLOSE-OPEN));
BUYpan1:=IF(CLOSE>OPEN,VAR1*(HIGH-LOW),IF(CLOSE< OPEN,VAR1*((HIGH-OPEN)+(CLOSE-LOW)),VOL/2));
SELLpan1:=IF(CLOSE>OPEN,0-VAR1*((HIGH-CLOSE)+(OPEN-LOW)),IF(CLOSE< OPEN,0-VAR1*(HIGH-LOW),0-VOL/2));
GSKZ1:=(BUYpan1-(-SELLpan1))/LIANG*换手;
GSKZ11:=SUM(GSKZ1,6);
GSKZ12:=MA(GSKZ11,5);
GPZBGS8:=GSKZ11>GSKZ12;
换手率:=VOL/CAPITAL*100;
BUY入:GPZBGS1 AND GPZBGS2 AND GPZBGS3 AND GPZBGS4 AND GPZBGS5 AND GPZBGS6 AND GPZBGS7 AND GPZBGS8 AND 换手率>3, COLORYELLOW, LINETHICK2;
1、该选股公式为条件选股，单日使用非时间段，且为收盘后下载盘后完整数据后使用；
因为该选股公式使用了EMA、SMA等移动平均线指标，这些指标需要收盘价才能计算。另外，文档中的RSI、LWR等指标也基于收盘价计算。因此，这些指标都只能在收盘后计算出结果。
此外，文档中的一些选股条件，比如“买盘”、“卖盘”、“买卖差”等，也需要根据当天的成交量数据计算，而这些数据同样只能在收盘后才能得到。
2、关于参数调整。
例如N1、N2、N3、N4等，这些参数直接影响指标的灵敏度，可以根据不同的市场情况调整。
比如换手率，默认是3，可以适当调大数值（对应代码为最后一行中“换手率>3”），在于自身选股经验和意向。
换手率阈值没有固定的标准，通常根据具体股票的流通股本大小、历史换手率、市场活跃程度等因素来设置。一般来说，可以将换手率阈值设置在5%-10%之间，但对于大盘股，这个阈值可能会更小；对于小盘股或概念股，这个阈值可能会更大。
例如，可以尝试设置换手率阈值为5%、10%或15%，然后观察其在该阈值下是否有效，并据此调整阈值以找到最佳设置。通常，一个合适的换手率阈值应该能够较好地反映市场活跃程度，既不过于频繁，也不失真。因此，投资者需要根据自身经验以及对特定股票的理解来调整这个阈值。
N1赋值:3
N2赋值:5
N3赋值:8
N4赋值:13
DIFF赋值:收盘价的N3日指数移动平均-收盘价的N4日指数移动平均
DEA赋值:DIFF的N2日指数移动平均
GPZBGS1赋值:DIFF>DEA
RSGPZB21赋值:(收盘价-N3日内最低价的最低值)/(N3日内最高价的最高值-N3日内最低价的最低值)*100
K赋值:RSGPZB21的N1日[1日权重]移动平均
D赋值:K的N1日[1日权重]移动平均
GPZBGS2赋值:K>D
LC赋值:1日前的收盘价
RSI1赋值:(收盘价-LC和0的较大值的N2日[1日权重]移动平均)/(收盘价-LC的绝对值的N2日[1日权重]移动平均)*100
RSI2赋值:(收盘价-LC和0的较大值的N4日[1日权重]移动平均)/(收盘价-LC的绝对值的N4日[1日权重]移动平均)*100
GPZBGS3赋值:RSI1>RSI2
RSV赋值:-(N4日内最高价的最高值-收盘价)/(N4日内最高价的最高值-N4日内最低价的最低值)*100
LWR1赋值:RSV的N1日[1日权重]移动平均
LWR2赋值:LWR1的N1日[1日权重]移动平均
GPZBGS4赋值:LWR1>LWR2
BBI赋值:(收盘价的N1日简单移动平均+收盘价的N2日简单移动平均+收盘价的N3日简单移动平均+收盘价的N4日简单移动平均)/4
GPZBGS5赋值:收盘价>BBI
GPZB赋值:收盘价-1日前的收盘价
MMS赋值:100*GPZB的N2日指数移动平均的N1日指数移动平均/GPZB的绝对值的N2日指数移动平均的N1日指数移动平均
MMM赋值:100*GPZB的N4日指数移动平均的N3日指数移动平均/GPZB的绝对值的N4日指数移动平均的N3日指数移动平均
GPZBGS6赋值:MMS>MMM
WJ赋值:(最高价+最低价+收盘价)/3
GPZB21赋值:如果最高价=最低价,返回1,否则返回最高价-开盘价和收盘价的较大值
GPZB22赋值:如果最高价=最低价,返回1,否则返回收盘价和开盘价的较大值-WJ
GPZB23赋值:如果最高价=最低价,返回1,否则返回开盘价和收盘价的较小值-最低价
GPZB24赋值:如果最高价=最低价,返回1,否则返回WJ-收盘价和开盘价的较小值
GPZB25赋值:成交量(手)/如果最高价=最低价,返回4,否则返回最高价-最低价
GPZB26赋值:(GPZB21*GPZB25)
GPZB27赋值:(GPZB22*GPZB25)
GPZB28赋值:(GPZB23*GPZB25)
GPZB29赋值:(GPZB24*GPZB25)
买盘赋值:(GPZB29+GPZB28)
卖盘赋值:(GPZB26+GPZB27)
买卖差赋值:买盘-卖盘
DDX赋值:买卖差
DX赋值:买卖差的5日简单移动平均*20
DDX1赋值:DX的3日[1日权重]移动平均
DDX2赋值:DDX1的3日[1日权重]移动平均
DDX3赋值:(5*DDX2+4*1日前的DDX2+3*2日前的DDX2+2*3日前的DDX2+4日前的DDX2)/15
GPZBGS7赋值:DDX1>DDX2
量赋值:成交量(手)
换手赋值:成交量(手)/当前流通股本(手)*100
VAR1赋值:成交量(手)/((最高价-最低价)*2-收盘价-开盘价的绝对值)
买盘1赋值:如果收阳线,返回VAR1*(最高价-最低价),否则返回如果收阴线,返回VAR1*((最高价-开盘价)+(收盘价-最低价)),否则返回成交量(手)/2
卖盘1赋值:如果收阳线,返回0-VAR1*((最高价-收盘价)+(开盘价-最低价)),否则返回如果收阴线,返回0-VAR1*(最高价-最低价),否则返回0-成交量(手)/2
GSKZ1赋值:(买盘1-(-卖盘1))/量*换手
GSKZ11赋值:GSKZ1的6日累和
GSKZ12赋值:GSKZ11的5日简单移动平均
GPZBGS8赋值:GSKZ11>GSKZ12
换手率赋值:成交量(手)/当前流通股本(手)*100
输出买入:GPZBGS1 AND GPZBGS2 AND GPZBGS3 AND GPZBGS4 AND GPZBGS5 AND GPZBGS6 AND GPZBGS7 AND GPZBGS8 AND 换手率>3, 画黄色, 线宽为2
热点信息
-
通达信资推价强榜单明星公式通过计算包括移动平均线、指数移动平均线、价格预测、成交量分析等关键指标，用...
-
通达信强弱关注价综动量选股公式 结合了移动平均线、相对强弱指标RSV、MACD等多维度信号，能够有效...
